Сообщения, отправленные пользователем: sayunot

по многочисленным письмам, кидаю пример) дата актуальности - 7.02. как сейчас - не знаю, т.к. писал интеграцию по просьбе - написал, отдал, забыл)
итак:
1. добавляем в конфигу след. пакеты:
- http://api.vetrf.ru/schema/cdm/base
- http://api.vetrf.ru/schema/cdm/application
- http://api.vetrf.ru/schema/cdm/argus/common
- http://api.vetrf.ru/schema/cdm/ikar
- http://api.vetrf.ru/schema/cdm/cerberus/enterprise
- http://api.vetrf.ru/schema/cdm/argus/shipment
- http://api.vetrf.ru/schema/cdm/argus/production
- http://api.vetrf.ru/schema/cdm/mercury/vet-document
- http://api.vetrf.ru/schema/cdm/mercury/applications
- http://schemas.xmlsoap.org/soap/envelope/

2. в пакете http://api.vetrf.ru/schema/cdm/application типы ApplicationDataWrapper и ApplicationResultWrapper делаем открытыми

3. добавляем ws ссылку http://api.vetrf.ru/schema/platform/services/ApplicationManagementService_v1.2.wsdl

4. дальше комменты из обработки:

// получаем определение сервиса и берем из него фабрику
// ВетисAPI = http://api.vetrf.ru/schema/platform/services/ApplicationManagementService_v1.2.wsdl
ОпределениеWS = WSСсылки.ВетисAPI.ПолучитьWSОпределения();

// создаем врем. фабрику на основе пакетов из конфиги и web сервиса
// нам нужны 2 пакета из ws, но пакет с application нужен локальный
МассивURI = Новый Массив;
МассивURI.Добавить("http://api.vetrf.ru/schema/cdm/application/ws-definitions");
МассивURI.Добавить("http://api.vetrf.ru/schema/cdm/base/ws-definitions");

ФабрикаWS = Новый ФабрикаXDTO(ОпределениеWS.ФабрикаXDTO.ЭкспортМоделиXDTO(МассивURI), ФабрикаXDTO.Пакеты);

// добавим 2 пакета, которые нужны, но есть только локально
Пакеты = Новый Массив;
Пакеты.Добавить(ФабрикаXDTO.Пакеты.Получить("http://api.vetrf.ru/schema/cdm/mercury/applications"));
Пакеты.Добавить(ФабрикаXDTO.Пакеты.Получить("http://schemas.xmlsoap.org/soap/envelope/"));
Для Каждого Пакет Из ФабрикаWS.Пакеты Цикл
	Пакеты.Добавить(Пакет);
КонецЦикла;

// создаем общую фабрику
ФабрикаXD = Новый ФабрикаXDTO(, Пакеты);

// создаем пробный узел Меркурия, MercuryApplicationRequest. используем теста ради
// в реальности на месте этого запроса может (и должен) быть любой другой из этого пакета
MercRequestDO = ФабрикаXD.Создать("http://api.vetrf.ru/schema/cdm/mercury/applications", "MercuryApplicationRequest");
// я сразу инициализую все узлы объекта методом, что ниже, имхо там удобнее
// ИнициализироватьОбъектXDTO(MercRequestDO, ФабрикаXD);

// определяем свойства и их значения для заполнения.
// можно, конечно, и напрямую указать для каждого свойства значение,
// но т.к. запросы будут разные, проще для каждого составить свое соответствие
// и использовать общий метод
MercRequestPM = Новый Соответствие;
MercRequestPM.Вставить("localTransactionId", вашID);
MercRequestPM.Вставить("initiator/login", login);
// тож мой локальный метод
// ЗаполнитьСвойстваОбъектаXDTO(MercRequestDO, MercRequestPM);

// создаем нужный запрос, инициализируем, заполняем свойства
SubmitRequestDO = ФабрикаXD.Создать("http://api.vetrf.ru/schema/cdm/application/ws-definitions", "submitApplicationRequest");

ИнициализироватьОбъектXDTO(SubmitRequestDO, ФабрикаXD);

SubmitRequestPM = Новый Соответствие;
SubmitRequestPM.Вставить("apiKey", apiKey);
SubmitRequestPM.Вставить("application/serviceId", "mercury-g2b.service");
SubmitRequestPM.Вставить("application/issuerId", issuerID);
SubmitRequestPM.Вставить("application/issueDate", ТекущаяДата());

ЗаполнитьСвойстваОбъектаXDTO(SubmitRequestDO, SubmitRequestPM);

// добавляем в блок data mercury request
SubmitRequestDO.application.data.Добавить(ФормаXML.Элемент, MercRequestDO.Тип().URIПространстваИмен, "mercuryApplicationRequest", MercRequestDO);

// создаем корневой узел, инициализируем
EnvelopeDO = ФабрикаXD.Создать("http://schemas.xmlsoap.org/soap/envelope/", "Envelope");

ИнициализироватьОбъектXDTO(EnvelopeDO, ФабрикаXD);

// добавляем submitApplicationRequest в блок body и готово!)
EnvelopeDO.body.Добавить(ФормаXML.Элемент, SubmitRequestDO.Тип().URIПространстваИмен, "submitApplicationRequest", SubmitRequestDO);

// получившийся объект можем выгружать во что угодно и передавать каким угодно способом, например, так:
ТелоXML = Новый ЗаписьXML;
ТелоXML.УстановитьСтроку("UTF-8");

ФабрикаXD.ЗаписатьXML(ТелоXML, EnvelopeDO);

ЗапросWeb = Новый HTTPЗапрос("platform/services/ApplicationManagementService");
ЗапросWeb.УстановитьТелоИзСтроки(ТелоXML.Закрыть());

СоединениеWeb = Новый HTTPСоединение("api2.vetrf.ru", 8002, login, password,,Истина);
ОтветWeb = СоединениеWeb.ОтправитьДляОбработки(ЗапросWeb);
Если (ОтветWeb.КодСостояния = 200) Тогда // значит, все ок
	// десериализуем
	ОтветXML = Новый ЧтениеXML;
	ОтветXML.УстановитьСтроку(ОтветWeb.ПолучитьТелоКакСтроку("UTF-8"));
	
	MercAppDO = ФабрикаXD.ПрочитатьXML(ОтветXML, EnvelopeDO.Тип()).Body.submitApplicationResponse.application;
	
	// возможные статусы:
	// ACCEPTED   Заявка принята.
	// IN_PROCESS Заявка обрабатывается.
	// COMPLETED  Заявка успешно обработана.
	// REJECTED   Заявка отклонена.
	Если (MercAppDO.status = "ACCEPTED") Тогда
		// тут шлем запрос на подтверждение
	КонецЕсли;
КонецЕсли;

Richi wrote:Добрый вам коллеги. Через XDTO не удается обработать заявку в системе. только через HTTP xml запросом. Так как ApplicationDataWrapper.dataApplication имеет Абстрактный тип и 1С не удается создать такой объект. в Ветисе пообещали что со временем они исправят это. но когда? не понятно. так что пока только через прямые запросы обращаться к функции.

я пока так сделал - изменил локальный пакет с dataApplication и applicationResultData, сделал эти типы открытыми, чтоб можно было свои запросы туда помещать. затем на основе локальных пакетов и пакетов из ws создаю общую фабрику. ну, а дальше - дело техники: работаем с получившейся фабрикой, строим запросы, используем записьxml , помещаем в тело http запроса. получаем ответ - используем чтениеxml, десериализуем при помощи созданной ранее фабрики

2pchernov: проверьте, что у "ПроксиПодсистемаОбработкиЗаявок" задан пользователь и пароль, перед тем как submitApplicationRequest вызываете.
а вообще 1С, по крайней мере 8.2, с текущей реализацией http://api.vetrf.ru/schema/platform/services/ApplicationManagementService_v1.2.wsdl работать напрямую не будет, из-за того, как объявлен wraper'ы в application:

<xs:complexType name="ApplicationDataWrapper">
<xs:sequence>
<xs:element ref="tns:applicationData" minOccurs="1" maxOccurs="1"/>
</xs:sequence>
</xs:complexType>
<xs:complexType name="ApplicationResultWrapper">
<xs:sequence>
<xs:element ref="tns:applicationResultData" minOccurs="1" maxOccurs="1"/>
</xs:sequence>
</xs:complexType>

applicationData и applicationResultData - это ссылки на абстрактные типы, т.е. предполагается, что в ApplicationDataWrapper и ApplicationResultWrapper будут добавлены ссылки на наследников этих типов. в случае с Меркурием - ссылки на наследников, например, MercuryApplicationRequest из пакета http://api.vetrf.ru/schema/cdm/mercury/applications. но 1С-ка так сделать не позволит, потому что не поддерживает подобные свойства у типов объектов в xdto-пакетах, так, как требуется. т.е. для 1С-ны applicationData в ApplicationDataWrapper это не просто ссылка с определенным типом, а вполне себе именованное свойство с абстрактным типом.

а можно более точно их назвать? потому что ответ в лучших традициях наших чиновников - это, конечно, весело, но и прямая работа с https://api2.vetrf.ru:8002/platform/services/ApplicationManagementService + пихание xml в тело запроса не годится.
или пока хотя бы включите в http://api.vetrf.ru/schema/platform/services/ApplicationManagementService_v1.2.wsdl поддержку типа http://api.vetrf.ru/schema/cdm/mercury/applications как свойства application.data.
в принципе, этого должно хватить, т.к создать application с нужным свойством на основе тех xd, что есть, мы и сами можем.
дальше. раз взялись вести wiki, заполните наконец-то раздел про меркурий в http://help.vetrf.ru/wiki/NameSpaces, сейчас там только вот это:

http://api.vetrf.ru/schema/cdm/mercury/applications
Пространство имён объектов, описывающих сущности меркурия.
Вернуться к началу ↑

p.s. на счет нормальных сервисов и примеров. тов. Александр Осминин, как-нибудь, на досуге, смеха ради, посмотрите документацию от google для android sdk. ну, чтоб понятно было, к чему стремиться надо.